SAP 特征 Classification

SAP小白kenny

已于 2022-08-02 16:36:21 修改

阅读量4.6k

点赞数 6

分类专栏： ABAP 文章标签： SAP

于 2022-08-02 11:37:57 首次发布

本文链接：https://blog.csdn.net/weixin_42646630/article/details/126116060

版权

ABAP 专栏收录该内容

123 篇文章 34 订阅

订阅专栏

一、前言

SAP Classification 为了方便查询定义的一套技术体系。其实是建立了一个大树（根节点在上面），大致层次 Class Type>Class>characteristics .参见下图：

分类系统允许您使用特征来描述所有类型的对象，并将类似的对象分组到类中——换句话说，就是对对象进行分类，以便稍后更容易地找到它们。

然后使用这些类帮助您更容易地找到对象，使用它们中定义的特征作为搜索条件。这确保您可以尽可能快地找到具有相似或相同特征的对象。

二、批次管理

批次管理（特性、类）：
业务场景：通常批次管理是为了控制某些属性，例如先进先出（先入库的先出库）。即入库批次需要关联相关属性。

业务举例：批次A：2019.12.21入库、B：2020.12.22入库。现要求先发货入库时间早的批次，此时出库就需要先发A批次，为了实现上述，将特性指定到批次，再将特性关联到类class。

业务模拟：

（工厂层级批次管理参考表MCHA，物料层级批次管理参考表MCH1，可通过SE11查看该表字段，对其进行批次管理）

1、建立批次特性（本文采用表MCH1中字段LWEDT最近的收货日期建立特性）

2、建立类，并将特性关联该类：

其中分类的类型022（如果你的批次层次是工厂级别的），其他情况选择023.

3、进入物料主数据，为物料建立分类（分配类别、关联特性，不用手工输入特性值），激活批次管理：

通过以上3步骤配置，就可以做批次管理业务了。

4、ME21N建立采购订单，MIGO将所有未清采购都入库时，系统自动输入最后收货时间作为批次的特性：

入库的时候，会自动将最后的收货日期写到对应生成的批次属性。至于哪些属性/特性关联该批次，取决于物料主数据分类是否分配类类型和特性。

5、MSC3N可以查看批次（由批次查看到批次对应的特性值，即最后的收货日期）

（下图来源与别处。为何我在模拟业务时，使用ME21N创建PO再MIGO全部收货或者MB1C使用MVT561做业务都生成了批次，但在批次中未产生最后收货日期特性值？不能自动生成如下的特性值）

有了批次258： 2010.3.1，259：2010.3.2，只需要后台配置策略，即可实现先进先出--根据最近的收货日期，值越小先出库。具体配置见下文。

三、创建特征特性

系统通过类类型Class Type来区分不同的应用，譬如类类型001为物料分类，类类型010为供应商分类，类类型022/023为批次分类。

Characteristic是sap用来描述物料特性的，这里所说的物料包含原材料，机械设备等。

对于一个原材料，它的密度，比热，存储温度等都是它的特性。可以根据这个原材料的特性来判断它生产出来的产品的等级。

对于一台机械设备，它的功耗，一次最长使用时间，以及生产的产品规格等都是它的属性。可以根据它的特性来制定生产计划，工艺流程等。

这就是Characteristic存在的意义。

1、Defining the Properties of Objects 自定义特征（Characteristics）

事务： CT04

2、Creating Classes

3、Assigning Objects

然后把特性分配给物料MM01或者CL20N

四、注意

创建特征和分类时的注意点

特征属性

应根据需要设置特征的格式、属性、长度、是否允许多选；

系统支持输入大于、小于等符号。

值检查
值检查时指系统进行检查输入值是否在允许的值中，同时为输入提供搜索帮助，应尽量设置只能从可选值中进行选择，系统支持有四种方法进行限制，如
创建特征时输入允许的特征值（如特征Z101）,为了便于输入特征值，系统还支持层次式的特征值，如销售地区，第一层为大区，第二层为省份，第三层为城市，这样选择起来就非常方便。
设置检查表Check Table（如特征Z105，系统限制只能从供应商主数据中选择供应商代码）;
在必要的情况下，我们可以建立自定义视图、函数（Function module）来对特征允许输入的值进行限制；
附加数据中的参考表字段起着二个作用。

1）参考表字段的格式将作为特征的格式；

2）在特定条件下，可以将参考字段的值复制到特征的值
对于物料而言，系统可以将表MARA中的值复制到物料分类的特征值中。
对于批次管理，系统可以将表MCH1/MCHA（批次主数据表）的字段值复制到特征。
对于采购审批，系统可以将表CEBAN/CEKKO（采购凭证表）的字段值复制到特征中，用于采购审批.

3）注意不起限制字段值（Check Table）的作用；

五、查询

1、查询特性分类

a) 查看对象的特征值（事务代码CL6BN）

该报表可以查看物料分类、供应商分类、客户分类等各种类型的分类的特征值，并可将结果导出。在本例中，我们查看物料分类，输入类Z100，类对象001，对象表MARA。（供应商对象分类为010，对象表LFA1）

如果仅需显示某个特征的值，如使用人群，则可以勾选“选择特性“

如果需要显示特定物料的值，则可以勾选“选择对象“，通过在对象输入框中点击”下一页”从而支持输入多个范围值。

b) 根据特征值查找对象

事务代码：CL30N，输入譬如颜色为红色的查询条件，查询到相应的物料。

注意类有三个状态：审批、锁定、未完成，只有审批的才会在本报表中出现。

2. 报表查询-根据分类中的特征查询库存和对象。

事务代码：MMCL可以根据特征值查询库存。

事务代码：OMILL_MMCL用来定义选择参数文件。

执行结果如下，可以查看到所有红色的物料的库存

备注：该功能需启用离散行业DIMP组件，未启用的话，可以通过先输入SE93，然后输入事务代码MMCL,执行效果稍有差异。

六、代码

1、获取类别

方法一、

L_OBJECTNAME = MARA-MATNR.
CALL FUNCTION ‘BAPI_OBJCL_GET_KEY_OF_OBJECT’
EXPORTING
OBJECTNAME = L_OBJECTNAME
OBJECTTABLE = ‘MARA’
CLASSTYPE = ‘300′
IMPORTING
CLOBJECTKEYOUT = L_CLOBJECTKEYOUT
TABLES
RETURN = LT_RETURN.

CALL FUNCTION ‘BAPI_OBJCL_GETCLASSES_KEY’
EXPORTING
CLOBJECTKEYIN = L_CLOBJECTKEYOUT
READ_VALUATIONS = ‘X’
TABLES
ALLOCLIST = LT_ALLOC_LIST
ALLOCVALUESCHAR = LT_ALLOCVALUESCHAR
RETURN = LT_RETURN.

第一个Function获取物料的分类对象号，第二个Function读取对象的分类值。

方法二

还有另外一个方式获取物料的默认特征值配置，此方法一般用于通过物料特征创建车辆、销售订单等对象的BAPI处理

CALL FUNCTION 'BAPI_OBJCL_GET_KEY_OF_OBJECT'
        EXPORTING
          OBJECTNAME     = MARA-MATNR "物料号
          OBJECTTABLE    = 'MARA'     "
          CLASSTYPE      = '300'      "类别种类（具体值参考表TCLA）
        IMPORTING
          CLOBJECTKEYOUT = G_CLASS
        TABLES
          RETURN         = IT_RETURN.

CALL FUNCTION 'BAPI_CLASS_GETDETAIL'
        EXPORTING
          CLASSTYPE            = '300'
          CLASSNUM             = G_CLASS
        TABLES
          CLASSCHARACTERISTICS = IT_REF "特征
          CLASSCHARVALUES      = IT_VAL.     "默认特征值

第一个Function获取物料的分类对象号，第二个Function读取分类对象号的特征、特征值以及默认特征值。

SQL

SELECT               "取特征值
    OBJEK ,
    ATNAM,
    ATFOR,       " 数据类型
    MSEHI,       "单位
    ATINT,       "间隔值
    ATWRT,        "char特性值
    ATFLV,         "num特性值从
    ATFLB         "num间隔特性值到
    INTO TABLE @DATA(LT_AUSP)
    FROM AUSP
    INNER JOIN CABN ON CABN~ATINN = AUSP~ATINN
    INNER JOIN MARA ON AUSP~OBJEK = MARA~MATNR
    WHERE MATNR IN @S_MATNR
    AND MARA~MATNR IN @S_MATNR
      AND MARA~MTART IN @S_MTART
      AND MARA~MATKL IN @S_MATKL
    AND    KLART = '001'.

七、相关表

特性和分类所在table

KLAH -- 分类和分类类型的表头

KSML -- 类和分类类型对应的特性流水码

SWOR -- 类的描述

CABN -- 特性流水码和特性及特性描述

CAWN -- 特新的值

INOB -- 分配给物料的特性

AUSP -- 物料的特性值和描述

KLAH:记录用事务代码CL01在每个类类行下边建立的类别的相关信息.关键字为内部类号.

在创建类别时需要指定类别的特性.特性用事物代码CT04创建.

KSML:记录了每个类别下的特性值.已内部类别号为关键字段和表KLAH相关.

TCLA:记录了类类型的相关信息包括表信息.

CABN:记录了内部特性编号和特性名称的转换关系,以及特性的数据类型,长度,小数位,单位以及是否为范围值,字段:ATINT='X'.特性的格式信息可以用于通过RTTS(Runtime type services)动态生成变量.

CABNT:记录了特性的描述信息:主键为内部特性号和语言代码

AUSP:特性值:记录了特性的值,如果特性值是char类型则存放在ATWRT(特征值)字段,如果是num类型则存放在ATFLV(值从),如果特性为范围则结束值存放在ATFLB(值到)字段.主键为objek(对象,对于物料分类来说就是物料编码),ATINN(内部特性号).

Demo

function zpp_trace_c_batch_class.
*"----------------------------------------------------------------------
*"*"Local Interface:
*"  IMPORTING
*"     VALUE(I_MATNR) TYPE  MARA-MATNR
*"     VALUE(I_CHARG) TYPE  MCHA-CHARG
*"     VALUE(I_WERKS) TYPE  MCHA-WERKS
*"  EXPORTING
*"     REFERENCE(O_INOB) TYPE  INOB
*"     REFERENCE(O_KSSK) TYPE  KSSK
*"     REFERENCE(O_KLAH) TYPE  KLAH
*"     REFERENCE(O_OBJEK) TYPE  OBJNUM
*"     REFERENCE(O_OBTAB) TYPE  TABELLE
*"     REFERENCE(O_KLART) TYPE  KLASSENART
*"     REFERENCE(O_CLASS) TYPE  KLASSE_D
*"  EXCEPTIONS
*"      BATCH_CLASS_NOT_EXSIT
*"      CLASS_NOT_IN_ZPP_TRACE_12
*"      NON_HEAT_OR_COIL
*"      INCORRECT_CLASS
*"----------------------------------------------------------------------
*  data:l_objek  type  objnum,
*       l_obtab  type  tabelle,
*       l_klart  type  klassenart,
*       l_class  type  klasse_d.

*  data ls_inob type inob.
*  data ls_kssk type kssk.
*  data ls_klah type klah.

  call function 'VB_BATCH_2_CLASS_OBJECT'
    exporting
      i_matnr       = i_matnr
      i_charg       = i_charg
      i_werks       = i_werks
    importing
      e_objek       = o_objek
      e_obtab       = o_obtab
      e_klart       = o_klart
      e_class       = o_class
    exceptions
      error_message = 99
      others        = 1.

  select single * from inob into o_inob
    where klart = o_klart and obtab = o_obtab and objek = o_objek.
  if sy-subrc ne 0.
    message e181 with i_charg raising batch_class_not_exsit.
  endif.

  select single * from kssk into o_kssk where objek = o_inob-cuobj.
  select single * from klah into o_klah where clint = o_kssk-clint.

  if i_werks = '1721' and ( o_class = zph_trace_batch_class=>c_characteristic-class1
                         or o_class = zph_trace_batch_class=>c_characteristic-class2 ).

    if o_klah-class is initial.
      o_klah-class = o_class.
    endif.
  else.
    select count(*) from zpp_trace_12 where class = o_klah-class.
    if sy-subrc ne 0 AND i_werks ne '1701'.
      "Class &1 is not belong to PP traceablility. (Check table ZPP_TRACE_12
      message e088 with o_klah-class raising class_not_in_zpp_trace_12.
    endif.
  endif.

  data lt_char  type table of bapi_char with header line.
  data lt_char_value  type table of bapi_char_values with header line.

  clear:lt_char[],lt_char_value[].

  call function 'BAPI_CLASS_GET_CHARACTERISTICS'
    exporting
      classnum        = o_klah-class
      classtype       = o_inob-klart
    tables
      characteristics = lt_char
      char_values     = lt_char_value.

  data l_atnam_heat type cabn-atnam."
  data l_atnam_coil type cabn-atnam."
  data l_atnam_SUPP type cabn-atnam."

  if i_werks = '1721' and ( o_class = zph_trace_batch_class=>c_characteristic-class1
                         or o_class = zph_trace_batch_class=>c_characteristic-class2 ).
    if o_class = zph_trace_batch_class=>c_characteristic-class1."'TKPHS_SELECTION'.
      l_atnam_heat = zph_trace_batch_class=>c_characteristic-heatn1.
      l_atnam_coil = zph_trace_batch_class=>c_characteristic-coiln1.
    endif.

    if o_class = zph_trace_batch_class=>c_characteristic-class2."'TKPPIN_BATCH'.
      l_atnam_heat = zph_trace_batch_class=>c_characteristic-heatn2.
      l_atnam_coil = zph_trace_batch_class=>c_characteristic-coiln2.
    endif.
  endif.

  if i_werks = '1701' and o_class = zly_batch_class=>c_characteristic-class1."'TKLY_BATCH_CLASS'.
*    l_atnam_heat = c_tkly_characteristic-tkly_heat_number.
*    l_atnam_coil = c_tkly_characteristic-tkly_coil_number.
    l_atnam_heat = zly_batch_class=>c_characteristic-heatn1.
    l_atnam_coil = zly_batch_class=>c_characteristic-coiln1.
  endif.

  if i_werks = '1711' and
    ( o_class = 'PRO_2102_BATCH'
   or o_class = 'PRO_2104_BATCH'
   or o_class = 'PRO_2106_BATCH'
   or o_class = 'PRO_2108_BATCH'
   or o_class = 'PRO_2202_BATCH'
   or o_class = 'PRO_2204_BATCH'
   or o_class = 'PRO_2208_BATCH'
   or o_class = 'PRO_2210_BATCH'
   or o_class = 'PRO_2302_BATCH'
   or o_class = 'PRO_2304_BATCH'
   or o_class = 'PRO_2306_BATCH'
   or o_class = 'PRO_2308_BATCH'
   or o_class = 'PRO_2310_BATCH'
   or o_class = 'PUR_MAIN_BATCH' ).
    l_atnam_heat = c_characteristic-heatn.
    l_atnam_coil = c_characteristic-coiln.
**begin*******INS***********zhangyu******11.12.2020 09:15:07********************
    l_atnam_SUPP = c_characteristic-SUPPL.
**end*********INS***********zhangyu******11.12.2020 09:15:07********************
  endif.

  read table lt_char with key name_char = l_atnam_heat.
  if sy-subrc ne 0.
    "class &1 not contains heat or Coil/bundle characteristic.
*    message e105 with o_klah-class raising non_heat_or_coil.
  endif.

  read table lt_char with key name_char = l_atnam_coil.
  if sy-subrc ne 0.
    "class &1 not contains heat or Coil/bundle characteristic.
*    message e105 with o_klah-class raising non_heat_or_coil.
  endif.

  "Some times o_class from VB_BATCH_2_CLASS_OBJECT buffer not from DB. Need adjust it.
  if o_class ne o_klah-class and o_klah-class is not initial.
    o_class = o_klah-class.
  endif.
endfunction.

function zpp_trace_u_batch_character .
*"----------------------------------------------------------------------
*"*"Local Interface:
*"  IMPORTING
*"     VALUE(I_MATNR) TYPE  MARA-MATNR
*"     VALUE(I_CHARG) TYPE  MCHA-CHARG
*"     VALUE(I_WERKS) TYPE  MCHA-WERKS
*"     VALUE(I_CHARACTER) TYPE  ZPP_TRACE_PROCESS_CHARACTERS
*"     VALUE(NOT_COMMIT) TYPE  CHAR01 DEFAULT ''
*"  TABLES
*"      BAPIRET2 STRUCTURE  BAPIRET2 OPTIONAL
*"  EXCEPTIONS
*"      INCORRECT_MATERIAL_CLASS
*"      NON_PP_TRACE_CLASS
*"      BATCH_CHARACTER_UPDATE_ERROR
*"----------------------------------------------------------------------
  data:l_class type klah-class,
       l_obtab type tclt-obtab,
       l_cuobj type inob-cuobj.

  data: l_batch_objek type objnum,
        l_batch_klart type klassenart,
        l_batch_obtab type tabelle,
        l_batch_class type klasse_d,
        l_batch_cuobj type inob-cuobj.

  data ls_inob type inob.
  data ls_kssk type kssk.
  data ls_klah type klah.

  data ls_20 type zpp_trace_20.

  data l_numc type n length 8.

  data lt_characteristics type table of bapi_char with header line.
  data lt_char_value type table of bapi_char_values with header line.

  data lt_bapiret2           type table of bapiret2 with header line.
  data lt_alloc_values_num   type table of bapi1003_alloc_values_num  with header line.
  data lt_alloc_values_char  type table of bapi1003_alloc_values_char with header line.
  data lt_alloc_values_curr  type table of bapi1003_alloc_values_curr with header line.

  data l_text_info type c length 100.

  select single * from zpp_trace_20 into ls_20 where heatn = i_character-heatno.
  if sy-subrc eq 0.
    i_character-in_grdate = ls_20-fstgr.
  endif.

  message s142 with i_matnr i_charg into l_text_info.

  call function 'SAPGUI_PROGRESS_INDICATOR'
    exporting
      text = l_text_info.

  call function 'ZPP_TRACE_C_MATERIAL_CLASS'
    exporting
      i_matnr                   = i_matnr
    importing
      o_class                   = l_class
      o_obtab                   = l_obtab
      o_cuobj                   = l_cuobj
    exceptions
      material_class_not_exsit  = 1
      class_not_in_zpp_trace_12 = 2
      non_heat_or_coil          = 3
      others                    = 4.
  if sy-subrc <> 0.
*    message id sy-msgid type sy-msgty number sy-msgno
*            with sy-msgv1 sy-msgv2 sy-msgv3 sy-msgv4
*            raising incorrect_material_class.

    clear bapiret2.
    bapiret2-type       = sy-msgty.
    bapiret2-id         = sy-msgid.
    bapiret2-number     = sy-msgno.
    bapiret2-message_v1 = sy-msgv1.
    bapiret2-message_v2 = sy-msgv2.
    bapiret2-message_v3 = sy-msgv3.
    bapiret2-message_v4 = sy-msgv4.
    message id sy-msgid type 'S' number sy-msgno
            with sy-msgv1 sy-msgv2 sy-msgv3 sy-msgv4 into bapiret2-message.
    append bapiret2.

    message id bapiret2-id type bapiret2-type number bapiret2-number
            with bapiret2-message_v1
                 bapiret2-message_v2
                 bapiret2-message_v3
                 bapiret2-message_v4
            raising incorrect_material_class.
  endif.

  call function 'ZPP_TRACE_C_BATCH_CLASS'
    exporting
      i_matnr                   = i_matnr
      i_charg                   = i_charg
      i_werks                   = i_werks
    importing
      o_inob                    = ls_inob
      o_kssk                    = ls_kssk
      o_klah                    = ls_klah
      o_objek                   = l_batch_objek
      o_obtab                   = l_batch_obtab
      o_klart                   = l_batch_klart
      o_class                   = l_batch_class
    exceptions
      batch_class_not_exsit     = 1
      class_not_in_zpp_trace_12 = 2
      non_heat_or_coil          = 3
      incorrect_class           = 4
      others                    = 5.
  if sy-subrc ne 0 and sy-subrc ne 1.
*    message id sy-msgid type sy-msgty number sy-msgno
*            with sy-msgv1 sy-msgv2 sy-msgv3 sy-msgv4
*            raising incorrect_material_class.
    clear bapiret2.
    bapiret2-type       = sy-msgty.
    bapiret2-id         = sy-msgid.
    bapiret2-number     = sy-msgno.
    bapiret2-message_v1 = sy-msgv1.
    bapiret2-message_v2 = sy-msgv2.
    bapiret2-message_v3 = sy-msgv3.
    bapiret2-message_v4 = sy-msgv4.
    message id sy-msgid type 'S' number sy-msgno
            with sy-msgv1 sy-msgv2 sy-msgv3 sy-msgv4 into bapiret2-message.
    append bapiret2.

    message id bapiret2-id type bapiret2-type number bapiret2-number
            with bapiret2-message_v1
                 bapiret2-message_v2
                 bapiret2-message_v3
                 bapiret2-message_v4
            raising incorrect_material_class.
  endif.

  call function 'BAPI_CLASS_GET_CHARACTERISTICS'
    exporting
      classnum        = l_batch_class
      classtype       = l_batch_klart
    tables
      characteristics = lt_characteristics
      char_values     = lt_char_value.

  loop at lt_characteristics.
    call function 'ZPP_TRACE_CONVERSION_CHAR_OUT'
      exporting
        i_atnam   = lt_characteristics-name_char
        i_charact = i_character
      tables
        ot_num    = lt_alloc_values_num
        ot_char   = lt_alloc_values_char
        ot_curr   = lt_alloc_values_curr.
  endloop.


  call function 'CUOB_GET_NUMBER'
    exporting
      class_type       = l_batch_klart
      object_id        = l_batch_objek
      table            = l_batch_obtab
    importing
      object_number    = l_batch_cuobj
    exceptions
      lock_problem     = 1
      object_not_found = 2
      others           = 3.
  if l_batch_cuobj is initial.
    "Create batch character
    call function 'BAPI_OBJCL_CREATE'
      exporting
        objectkeynew    = l_batch_objek
        objecttablenew  = l_batch_obtab
        classnumnew     = l_batch_class
        classtypenew    = l_batch_klart
      tables
        allocvaluesnum  = lt_alloc_values_num
        allocvalueschar = lt_alloc_values_char
        allocvaluescurr = lt_alloc_values_curr
        return          = lt_bapiret2.

    call function 'ZPP_TRACE_U_CUOBJ_BM' in update task
      exporting
        i_matnr = i_matnr
        i_werks = i_werks
        i_charg = i_charg.
  else.
    "Update batch
    call function 'BAPI_OBJCL_CHANGE'
      exporting
        objectkey          = l_batch_objek
        objecttable        = l_batch_obtab
        classnum           = l_batch_class
        classtype          = l_batch_klart
      tables
        allocvaluesnumnew  = lt_alloc_values_num
        allocvaluescharnew = lt_alloc_values_char
        allocvaluescurrnew = lt_alloc_values_curr
        return             = lt_bapiret2.
  endif.

  clear bapiret2[].
  bapiret2[] = lt_bapiret2[].

  loop at lt_bapiret2 where type = 'A' or type = 'E'.
  endloop.
  if sy-subrc eq 0.
    if not_commit ne 'X'.
      call function 'BAPI_TRANSACTION_ROLLBACK'.
    endif.

    clear bapiret2.
    bapiret2-type       = 'E'.
    bapiret2-id         = 'ZPP_TRACE'.
    bapiret2-number     = '089'.
    bapiret2-message_v1 = i_matnr.
    bapiret2-message_v2 = i_charg.
    message s089 with i_matnr i_charg into bapiret2-message.
    append bapiret2.

    message e089 with i_matnr i_charg raising batch_character_update_error.


  else.
    if not_commit ne 'X'.
      call function 'BAPI_TRANSACTION_COMMIT'
        exporting
          wait = 'X'.
    endif.

    clear bapiret2.
    bapiret2-type       = 'S'.
    bapiret2-id         = 'ZPP_TRACE'.
    bapiret2-number     = '090'.
    bapiret2-message_v1 = i_matnr.
    bapiret2-message_v2 = i_charg.
    message s090 with i_matnr i_charg into bapiret2-message.
    append bapiret2.
  endif.

endfunction.